Használatához csak annyit kell tennünk hogy zip-ben található src mappából kimásoljuk a forrásokat a projectünk forrásai mellé majd a lent látható módon használhatjuk.
A szökséges fájlok letölthetőek innen: http://code.google.com/p/bulk-loader/downloads/list

BulkLoaderTest.as

package
{
	import br.com.stimuli.loading.BulkLoader;
	import br.com.stimuli.loading.BulkProgressEvent;

	import flash.display.Bitmap;
	import flash.display.Sprite;
	import flash.events.ErrorEvent;
	import flash.events.Event;
	import flash.net.URLRequest;
	import flash.net.URLRequestMethod;
	import flash.net.URLVariables;

	public class BulkLoaderTest extends Sprite
	{

		private var bulkLoader:BulkLoader;

		public function BulkLoaderTest()
		{
			bulkLoader = new BulkLoader("main")

			bulkLoader.add("data/sometext.txt", {id:"sometext", preventCache:true})
			bulkLoader.add("data/datafile1.xml", {id:"data1", preventCache:true})
			bulkLoader.add("data/datafile2.xml", {id:"data2", preventCache:true})
			bulkLoader.add("data/picture.jpg", {id:"picture"})

			// ------------ Post adatok küdése majd az eredmény betöltése
			var req:URLRequest = new URLRequest()
			req.url = "http://yourdomain.com/xmlgenerator.php"
			req.method = URLRequestMethod.POST

			var urlVars:URLVariables = new URLVariables()
			urlVars.postVar1 = "foo"
			req.data = urlVars

			bulkLoader.add(req ,{id:"generatedxml", type:"xml", preventCache:true})

			bulkLoader.addEventListener(BulkProgressEvent.PROGRESS, onLoadProgress)
			bulkLoader.addEventListener(BulkProgressEvent.COMPLETE, onLoadComplete)
			bulkLoader.addEventListener(BulkLoader.ERROR, onLoadError)

			bulkLoader.start()
		}

		private function onLoadProgress(event:BulkProgressEvent):void
		{
			trace("Betöltött fájlok: "+event.itemsLoaded)
			trace("Összes fájl: "+event.itemsTotal)
			trace("Betöltve százalék: "+(event.percentLoaded*100)+"%")
		}

		private function onLoadComplete(event:Event):void
		{
			var myText:String = bulkLoader.getText("sometext")
			var datafile1XML:XML = bulkLoader.getXML("data1")
			var datafile2XML:XML = bulkLoader.getXML("data2")
			var picture:Bitmap = bulkLoader.getBitmap("picture")

			var genXML:XML = bulkLoader.getXML("generatedxml")

			trace("Betöltés kész")
		}

		private function onLoadError(event:ErrorEvent):void
		{
			trace("Hiba betöltés közben: "+event.text)
		}
	}
}

Használata hasonlít az URLLoader-hez viszont az add metódusa segítségével adhatunk hozzá különböző betötendő fájlokra vagy skriptekre mutató útvonalat. Két paramétere van az elérési útvonal és egy paramétereket tartalmazó objektum amit az egyszerűség kedvéért általában a {} karakterek segítségéve hozhatunk létre.

• Az elérési útvonal lehet String vagy URLRequest típusú is utóbbi segítségével adatokat küldhetünk páldául php-nak majd a loader a választ fogja betölteni.
• A paraméterek objektum különböző beállításokat tárol, például az id megadásával később hivatkozni tudunk a betöltött tartalomra.  A preventCache egy random értéket küld a kéréssel együtt a webszervernek ami megakadályozza hogy a böngésző a cache-ből töltse vissza a fájljainkat viszont ez a beállítás csak akkor működik ha az swf a böngészőben fut.  A type segítségével megadhatjuk hogy milyen típusú adatot töltünk be, ez akkor lehet fontos ha például php-val generálunk egy xml-t és mivel az elérési útvonalból a loader nem tudja kitalálni a típust, meg kell adnunk { type:”xml” } formában.  A többi paraméterről a dokumentációban lehet információt találni.

Amikor a betöltés befejeződött a get… kezdetű metódusokkal és a már korábban megadott id segítségével kérhetjük le az adatokat amik a betöltendő tartalmaktól függően más más típusúak.

Hiba kezeléshez lehetőség van magához a loaderhez eseményfigyelőt adni vagy az add metódus által visszaadott LoadingItem-hez így külön kezelhetjük a hibákat vagy betöltési információkat.

További minták, magyarázatok és dokumentációk a BulkLoader google code tárhelyén találhatók.
http://code.google.com/p/bulk-loader/w/list